Práctica 3

Matrices

Como es conocido, la solución de un sistema lineal depende, exclusivamente, de la matriz de coeficientes y de los términos independientes. Por tanto, lo primero que necesitamos es saber escribir las matrices en Mathematica. Las matrices se escriben con ayuda de las llaves{} Estas se consiguen pulsando simultáneamente las teclas Alt Gr+ { o Alt Gr+ }. Dentro de ellas los elementos de cada fila de una matriz van entre llaves separados por comas. Si hay más de una fila, las diferentes filas van separadas por comas y entre llaves también. Las matrices así pueden se pueden escribir directamente, elemento a elemento.
A veces, si sus elementos proceden de evaluar cierta función o siguen una determinada regla de asignación, se pueden construir con Table.

  La sentencia Table tiene el siguiente formato 
  
			  Table[regla[i,j],{i, nº de filas},{j, nº de columnas}]
  

   He aquí algunos ejemplos:

A1=Table[1/(i+j),{i,5},{j,5}];

A2={{2,3,4,5,6},{3,4,5,6,7},{4,5,6,7,8},{5,6,7,8,9},{6,7,8,9,10}};

A3={{1,1,1,1,1},{1,1,1,1,1},{1,1,1,1,1},{1,1,1,1,1},{1,1,1,1,1}};

A4={{1,0},{0,0},{0,0},{0,0},{0,1}};
A5={0,1,0,0,0};

Podemos presentar las matrices en el formato que les es propio:

MatrixForm[A1]

MatrixForm[A2]

Se pueden introducir matrices haciendo uso de las paletas. Basta ir a File, Palettes, escoger Basic Calculations y dentro de ésta Lists and Matrices se selecciona una matriz y se va rellenando la primera fila . Si se necesitan más columnas se pulsa Ctrl+ , y aparecerá una nueva columna así hasta las que necesitemos. Si queremos nuevas filas pulsamos al rellenar el último elemento de la fila Ctrl+ ↵

 Las matrices A1 y A2 son de igual dimensión, 5x5, por lo que se pueden sumar, restar y si es posible invertir, esto es, si tienen determinante distinto de cero. La matriz A3 también se puede sumar, restar y multiplicar con las anteriores, pero no se puede invertir,  porque sus filas son idénticas y, por tanto, el determinante es cero. Cualquiera de las tres matrices primeras se puede multiplicar por A4 pero no se puede sumar ninguna de ellas con A4 en virtud de las dimensiones de unas y otras. Como Mathematica opera en modo simbólico, salvo que se indique lo contrario, si queremos ver los elementos de la matriz a1 con 2 cifras significativas, debemos pedir el valor numérico:

MatrixForm[N[A1,2]]

Cómo extraer elementos de una matriz

Si tomamos la matriz A2 arriba definida y queremos extraer su fila i-ésima se pide con la sentencia  A2[[i]]

A2[[3]]

Sin embargo, si escribe A2[[i,j]] nos aparece el elemento que está en la i-ésima fila y j-ésima columna

A2[[4, 3]]

La  sentencia  
                         Transpose[matriz] 
                         
  nos da la transpuesta de matriz. ¿Cómo se pide la j-ésima columna de una matriz dada?

Operaciones

Suma y resta de matrices.

La ejecución de las correspondientes celdillas mostrará cuáles de las siguientes operaciones no son posibles.

A1-A1

A2+A3

A1+A2+A3

A3+A4

Nótense los mensajes de error anteriores y la salida correspondiente.

Producto por escalares

Para ver cómo se multiplica una matriz por un escalar será suficiente que consideremos algunos ejemplos.

7A3

7*A3

A3/7

1/7 A3

Producto de matrices

Para multiplicar dos matrices hay que emplear el símbolo  "." entre ambas. Si se deja un espacio o se emplea el signo " * " lo que hace es multiplicar elemento a elemento entre los que ocupan la misma posición. Cuando una matriz es de tipo fila o columna Mathematica la considera convenientemente como tal y, por tanto, en los ejemplos anteriores es posible efectuar A5.A1 y A1.A5, pues, en el primer caso, considerada A5 como matriz fila, es posible  la multiplicación y, en el segundo caso, considerado como columna,  también es posible efectuar la multiplicación. A continuación se incluyen diferentes operaciones. Se observará que es posible efectuar algunas  y otras no.

A2.A3

A1.A2.A3

A3.A5

A4.A1

A5.A2

A5*A2

A2*A3

A4 A4

Una operación importante al trabajar con matrices cuadradas es hallar potencias de las mismas. Este problema se reduce a calcular el producto de una matriz consigo misma un determinado número de veces. Sin embargo, si la potencia es alta, para evitar la utilización  de una sentencia For o Do, Mathematica dispone de un comando que produce directamente el resultado buscado. Es

                                      MatrixPower[matriz,exponente].

   Si exponente es un número natural, proporciona la correspondiente potencia de la matriz, mientras que si es un entero negativo se obtiene como salida la potencia indicada de la matriz inversa (si matriz es invertible).

Por ejemplo, la cuarta potencia de la matriz A2 es

MatrixPower[A2,4]

Inversa, Traspuesta y Determinante de una matriz.

Las matrices inversa y traspuesta de una matriz, así como su determinante, se obtienen con las sentencias Inverse[matriz], Transpose[matriz], y Det[matriz], respectivamente. Las siguientes instrucciones permiten determinar si la matriz a1 considerada tiene inversa o no.

If[Det[A1]==0,
   Print["la matriz considerada no tiene inversa"],
   A11=Inverse[A1]
   ]

Podemos hallar su determinante, así como presentarla en formato matricial.

Det[A1]

MatrixForm[A11.A1]

También podemos hallar el determinante de la matriz A2.

Det[A2]

Esta matriz, en consecuencia, no tiene inversa.

Consideremos una nueva matriz y algunos hechos sobre ella.

M={{5,0,0,0,0},{2,4,0,0,0},{1,0,6,0,0},{1,1,1,1,0},{2,0,1,0,1}};

MatrixForm[M]

Det[M]

iM=Inverse[M]

MatrixForm[iM]

Det[iM]

MatrixForm[Transpose[M]]

Rango de una matriz

Una operación que hay que efectuar a menudo al tratar problemas en los que intervienen matrices consiste en calcular el rango. Disponemos de varios procedimientos, de los que vamos a reflejar dos.

Reducción de la matriz por filas

Otro método para determinar el rango de una matriz es someterla a transformaciones elementales por filas, lo que se consigue con la orden RowReduce.

Vemos cómo funciona con la misma matriz numérica de la subsección anterior, que debe ser redefinida.

matriz=Table[i+j,{i,5},{j,3}];
RowReduce[matriz]
MatrixForm[%]

Apreciamos que se obtiene un matriz equivalente a la original con tres filas nulas, lo que indica que el rango es dos ¿Se puede saber con este método qué filas y columnas de la matriz de partida proporcionan la submatriz de orden igual al rango con determinante no nulo?.

Responderemos con un ejemplo. Definimos una matriz muy simple.

matriz={{0,0,1,0,0},{0,0,0,1,0},{0,0,1,1,0},{0,0,1,0,1},{0,0,0,0,1}};
MatrixForm[matriz]

La reducimos.

RowReduce[matriz]//MatrixForm

Se podría pensar que con las tres últimas columnas de las tres primeras filas se obtendría una submatriz de la matriz considerada inicialmente de orden tres de determinante no nulo. Sin embargo, se comprueba  inmediatamente que tal submatriz tiene determinante nulo. En consecuencia, la función RowReduce proporciona información sobre el rango de la matriz, entre otras cosa, pero no debe usarse para establecer qué ecuaciones daban la solución del problema o qué vectores generadores de un espacio son los linealmente independientes.

Menores de una matriz.

La forma habitual de determinar el rango de una matriz consiste en determinar el orden máximo de las submatrices cuadradas con determinante no nulo. Para ello utilizamos la sentencia

                            Minors[matriz,orden]

   Produce los menores de la matriz indicada del orden que se especifica. Conviene presentar un ejemplo.

Definimos una matriz.

matriz=Table[i+j,{i,5},{j,3}]

Su rango puede ser, a lo sumo, tres. Hallamos, por tanto, los menores de orden tres.

Minors[matriz,3]

Observamos que todos son nulos, por lo que el rango es inferior a tres.

Pasamos a los de orden dos.

Minors[matriz,2]

Como alguno de ellos es no nulo (realmente, todos), la matriz es de rango dos.

Si quisiésemos saber qué filas y columnas son las que producen un menor de orden igual al rango, deberíamos conocer la forma de operar de la orden Minors. Para ello, definiremos un matriz arbitraria de un orde determinado y le aplicaremos la mencionada instrucción.

matriz=Table[a[i,j],{i,5},{j,3}];

Es inmediato ver cómo opera Minors para producir los menores de orden uno.

Minors[matriz,1]

¿Cómo actúa con los de orden dos?.

menores2=Minors[matriz,2];

La lista anterior, que no ha sido mostrada por contener un número elevado de elementos, es de orden 10x3, como se comprueba fácilmente:

Dimensions[menores2]

Veamos su primera lista componente.

menores2[[1]]

Su primer elemento es

menores2[[1,1]]

Es el determinante asociado a la submatriz

                            {{a[1,1],a[1,2]},
                              {a[2,1],a[2,2]}}

de la matriz considerada, formada con las columnas primera y segunda de las filas primera y segunda.

El segundo elemento es

menores2[[1,2]]

Es el determinante asociado a la submatriz

                            {{a[1,1],a[1,3]},
                              {a[2,1],a[2,3]}}

de la matriz considerada, formada con las columnas primera y tercera de las filas primera y segunda.

Por último, el tercer elemento es

menores2[[1,3]]

Corresponde al determinante asociado a la submatriz

                            {{a[1,2],a[1,3]},
                              {a[2,2],a[2,3]}}

de la matriz considerada, formada también con las columnas segunda y tercera de las filas primera y segunda.

Es inmediato comprobar que la lista segunda de menores2 consta de similares determinantes pero correspondientes a las filas primera y tercera de la matriz de partida. Lo mismo sucede con las restantes. Se recomienda analizar el comportamiento de Minors en lo que se refiere a los de orden tres.

Ejercicios

1. Crea con la sentencia Table una matriz 6x 6 cuyos elementos sean la suma de su número de fila y su número de columna.
2. Calcula el rango de la matriz del ejercicio 1.
3. Dada la matriz A=  (({{2, -1, -1}, {-1, 3, 1}, {1, 1, 3}})), razone si tiene inversa. Si es así, calcúlela por medio de operaciones elementales por filas, tal y como se ha hecho en clase. ¿Coincide con la que nos proporciona Mathematica directamente?

4. Dado el sistema            2x-3y+z = -2
                                2x+y-z = 1
                                3x+2y+3z = 1
   determine qué tipo de sistema es según nos asegura el teorema de Rouchè-Frobenius.