Práctica 6

Aplicaciones lineales

Clear["Global`*"]

En esta práctica estudiaremos cómo definir una aplicación lineal, cómo obtener su matriz respecto de distintas bases, y cómo hallar su núcleo y su imagen. (Basada en una práctica original de Antonio Palomares.)

Aplicaciones lineales y matrices.

Para definir una aplicación lineal usamos la notación con la que se definen las funciones, teniendo en cuenta que la función se aplica a un vector, y que devuelve un vector.

Como ejemplo, definimos f, una aplicación lineal de (ℝ^2) a (ℝ^3), es decir, que aplicada a un vector de (ℝ^2) da un vector de (ℝ^3).

f[{x_,y_}]:={x+y,x-y,2x+3y}

Para hallar la imagen por f de un vector, evaluamos la aplicación.

f[{1,2}]

Ejercicio: Defina la aplicación lineal f1 :  (ℝ^2) ⟶ (ℝ^4), dada por f1(x, y) = (2x, 3y, 2x+y, -x-2y). Halle la imagen por f1 del vector (2, -2).

Dada una aplicación lineal f : V ⟶ W, si fijamos una base en el espacio de partida B = {v1, v2, ..., vn}, la aplicación f está completamente determinada si conocemos las imágenes por f de los vectores de la base, esto es, basta conocer f(v1), f(v2), ..., f(vn).

En el ejemplo, basta conocer f[{1, 0}] y f[{0, 1}], ya que por linealidad f[{x, y}] = x f[{1, 0}] + y f[{0, 1}]. En concreto, si conocemos

f[{1,0}]
f[{0,1}]

la aplicación

g[{x_,y_}]:=x {1,1,2}+y {1,-1,3}

g[{x,y}]

es idéntica a la aplicación f.

También podemos definir una aplicación mediante una matriz, sólo tenemos que hallar las imágenes de los vectores de una base del espacio de partida, y poner estas imágenes como columnas de la matriz. Veremos los detalles en las siguientes secciones.

Por ejemplo, la aplicación

h[{x_,y_}]:=(({{1, 1}, {1, -1}, {2, 3}})).{x,y}

h[{x,y}]

es idéntica a la aplicación f.

Ejercicio: Considere la aplicación lineal f2 :  (ℝ^3) ⟶ (ℝ^2) dada por f2(x, y, z) = (x-y, y+z). Aplique f2 a los vectores de la base canónica de (ℝ^3), y utilize las imágenes para definir g2 de forma que sea una aplicación lineal igual a f2. Defina, usando una matriz, la aplicación lineal h2 que es también igual a f2.

Matriz de una aplicación respecto de las bases canónicas.

En general, dada una aplicación lineal  f : V ⟶ W, podemos encontrar una matriz que la represente, en el sentido de que multiplicar las componentes de un vector por la matriz es equivalente a evaluar la aplicación lineal sobre ese vector. Para obtener esta matriz debemos primero fijar una base B1 = {v1, v2, ..., vn} en el espacio de partida y una base B2 = {w1, w2, ..., wm} en el espacio de llegada, tras esto, hallamos los vectores f(v1), f(v2), ..., f(vn) y obtenemos sus coordenadas en la base B2. Al colocar estas coordenadas por columnas obtenemos una matriz que se dice la matriz asociada a f respecto de las bases B1 y B2.

Construyamos la matriz de la aplicación h :  (ℝ^2) ⟶ (ℝ^4) dada por h(x, y) = (2x+y, x+y, x-2y, -y), considerando en el espacio de partida la base canónica B1 de (ℝ^2), y en el espacio de llegada la base canónica de (ℝ^4). Observe cómo se definen las bases usando IdentityMatrix.

h[{x_,y_}]:={2x+y,x+y,x-2y,-y}
B1=IdentityMatrix[2]
B2=IdentityMatrix[4]

La primera columna de la matriz de la aplicación es h aplicada al primer vector de la base, esto es, aplicada a B1[[1]].

h[ B1[[1]] ]

La segunda columna de la matriz de la aplicación es h aplicada al segundo vector de la base.

h[ B1[[2]] ]

La siguiente matriz tiene por filas las imágenes por h de los vectores de la base B1.

m={ h[ B1[[1]] ], h[ B1[[2]] ]}

Si trasponemos esta última matriz, tendremos por columnas las imágenes por h de los vectores de B1.

MatrixForm[ Transpose[m] ]

De forma más corta, aunque menos clara, se podría haber obtenido esta última matriz evaluando h[B1].

Ejercicio: Defina la aplicación lineal g1 :  (ℝ^3) ⟶ (ℝ^2), dada por g1(x, y, z) = (y+z, x-y). Halle la matriz de la aplicación g1 respecto de la base canónica de  (ℝ^3) y la base canónica de  (ℝ^2).

Matriz de una aplicación respecto de bases cualesquiera.

Ahora veremos un ejemplo de cómo construir la matriz de una aplicación lineal respecto de bases cualesquiera. Consideramos la aplicación lineal f :  (ℝ^4) ⟶ (ℝ^2) dada por f(x, y, z, t) = (x+y+2z, x-z-3t) y la base B1 = {{1, 0, 1, 0}, {0, 1, 0, 1}, {1, 0, 0, 1}, {0, 1, 0, 0}} de (ℝ^4) y la base B2 = {{1, 1}, {0, -1}} de (ℝ^2).

En primer lugar definimos f y las dos bases, que podríamos comprobar que lo son usando el determinante o RowReduce.

f[{x_,y_,z_,t_}]:={x+y+2z,x-z-3t}

B1={{1,0,1,0},{0,1,0,1},{1,0,0,1},{0,1,0,0}}

B2={{1,1},{0,-1}}

Ahora debemos calcular las imágenes por f de los vectores de la base,  f[ B1[[1]] ], f[ B1[[2]] ], f[ B1[[3]] ] y f [ B1[[4]] ], y poner estos vectores en la base B2, es decir,  como combinación lineal de los vectores {1, 1} y {0, -1}. Consideremos primero el vector f[ B1[[1]] ]

f[B1[[1]]]

Debemos hallar coeficientes a y b de forma que a {1, 1} + b {0, -1} = {3, 0}, lo cual puede hacerse con una orden LinearSolve,

LinearSolve[(({{1, 0}, {1, -1}})),{3,0}]

La matriz de coefientes es la traspuesta de B2, con lo que se podría haber calculado la primera columna de la matriz como

c1=LinearSolve[ Transpose[B2],f[ B1[[1]] ] ]

Este mismo sistema se podría resover usando la inversa de la matriz de coeficientes, con lo que la primera columna se podría calcular también con la siguiente instrucción

Inverse[Transpose[B2]].f[B1[[1]]]

La segunda columna sería

c2=LinearSolve[ Transpose[B2],f[ B1[[2]] ] ]

De igual forma se podrían calcular la tercera y cuarta columna, pero vamos a hacerlo mediante otro método, usando la matriz de cambio de base, ya que lo que haremos es escribir el vector f[ B1[[3]] ], que está en la base canónica, en la base B2. Para ésto, recordamos de la práctica 5 que la matriz de cambio de base de B2 a la base canónica es Transpose[B2], y que la matriz de cambio de base que necesitamos ahora, que va de la base canónica a la base B2 es su inversa, es decir, Inverse[Transpose[B2]]. Por tanto la tercera columna de la matriz de la aplicación es

c3=Inverse[Transpose[B2]] . f[B1[[3]] ]

La cuarta columna, no importa el método usado, es

c4=Inverse[Transpose[B2]] . f[B1[[4]] ]

Si ponemos los vectores c1, c2, c3 y c4 por columnas, tendremos la matriz de f respecto de las bases B1 y B2.

MB1B2=Transpose[{c1,c2,c3,c4}]

MatrixForm[MB1B2]

Vamos a comprobar que la matriz calculada es la matriz de f respecto de las bases B1 y B2, para lo cual consideramos un vector {a, b, c, d} de  (ℝ^4) expresado en la base B1, es decir, los número a, b, c y d son las coordenadas del vector en la base B1. Aplicar f a ese vector es equivalente a multiplicarlo por la matriz de la aplicación

MB1B2.{a,b,c,d}

Pero el vector que resulta está en la base B2, lo pasamos a la base canónica usando la matriz de cambio de base de B2 a la base canónica.

DeB2aBC=Transpose[B2]

DeB2aBC.MB1B2.{a,b,c,d}

Ahora aplicamos f al mismo vector, para lo cual recordamos que el vector {a, b, c, d} dado en la base B1 es el vector a*B1[[1]] + b*B1[[2]] + c*B1[[3]] + d*B1[[4]] en la base canónica de (ℝ^4).

f[ a*B1[[1]]+b*B1[[2]]+c*B1[[3]]+d*B1[[4]]  ]

Ejercicio: Considere la aplicación lineal g:  (ℝ^3) ⟶ (ℝ^2) que verifica que g(v1) = {0,1}, g(v2) = {1,1}, g(v3) = {-1,1}, hallar su matriz respecto de las bases  B1 = {v1, v2, v3} y B2 = {{1, 0}, {1, 1}}.

Matriz de una aplicación respecto de distintas bases.

Si tenemos la matriz de una aplicación  f :  (ℝ^n) ⟶ (ℝ^m)  respecto de las bases canónicas, podemos hallar su matriz respecto de otras bases empleando matrices de cambio de base.

Supongamos que tenemos las coordenadas de un vector en la base B1, si multiplicamos estas coordenadas por la matriz de cambio de base de B1 a la base canónica de (ℝ^n), tendremos sus coordenadas en la base canónica. Si multiplicamos ahora esas coordenadas por la matriz de la aplicación respecto de las bases canónicas, tendremos las coordenadas de la imagen del vector respecto de la base canónica. Si queremos tener las coordenadas respecto de la base B2, debemos multiplicar por la matriz de cambio de base de la base canónica a la base B2.

Este procedimiento podría haberse usado para hallar la matriz de la sección anterior, es decir, la matriz de la aplicación f :  (ℝ^4) ⟶ (ℝ^2),  f(x, y, z, t) = (x+y+2z, x-z-3t) respecto de las bases B1 = {{1, 0, 1, 0}, {0, 1, 0, 1}, {1, 0, 0, 1}, {0, 1, 0, 0}} y B2 = {{1, 1}, {0, -1}}. Veamos cómo.

En primer lugar definimos la aplicación f y las bases B1 y B2.

f[{x_,y_,z_,t_}]:={x+y+2z,x-z-3t}

B1={{1,0,1,0},{0,1,0,1},{1,0,0,1},{0,1,0,0}}

B2={{1,1},{0,-1}}

Definimos la base canónica en (ℝ^4).

BC=IdentityMatrix[4]

La matriz de la aplicación f respecto de las bases canónica es

MBCBC=Transpose[ {f[ BC[[1]] ], f[ BC[[2]] ], f[ BC[[3]] ], f[ BC[[4]] ] } ]

Para efectuar el procedimiento descrito, debemos definir las matrices de cambio de base. Concretamente, la matriz de cambio de base de B1 a la base canónica de (ℝ^4) es

DeB1aBC=Transpose[B1]

y la matriz de cambio de base de la canónica de (ℝ^2) a B2 es

DeBCaB2=Inverse[Transpose[B2]]

Con las definiciones que hemos hecho, vamos a hallar la matriz de f respecto de las bases B1 y B2. Supongamos que tenemos un vector dado por sus coordenadas respecto de la base B1

v={a,b,c,d}

Para poder usar la matriz de f respecto de las bases canónicas, debemos expresar el vector respecto de la base canónica de  (ℝ^4)

DeB1aBC.v

Como el vector resultante está expresado en coordenadas respecto de la base canónica de (ℝ^4), si lo multiplicamos por la matriz MBCBC, que es la matriz de la aplicación respecto de las bases canónicas, tendremos la imagen de v respecto de la base canónica de (ℝ^2).

MBCBC.(DeB1aBC.v)

Si multiplicamos el vector resultante por la matriz de cambio de base de la canónica de (ℝ^2) a la base B2, tendremos las coordenadas de la imagen de v respecto de la base B2.

DeBCaB2.(MBCBC.DeB1aBC.v)

Por tanto para pasar de las coordenadas de un vector en la base B1 a las coordenadas de su imagen en la base B2, hemos multiplicado por la matriz DeBCaB2.MBCBC.DeB1aBC, en definitiva, la matriz de la aplicación f respecto de las bases B1 y B2 es

MB1B2=DeBCaB2.MBCBC.DeB1aBC

con lo que se comprueba el correspondiente resultado teórico sobre la matriz de una aplicación lineal respecto de distintas bases.

De esta igualdad, podemos despejar la matriz de f respecto de las bases canónicas si conocemos la matriz de f respecto de las bases B1 y B2.

MBCBC=Inverse[DeBCaB2].MB1B2.Inverse[DeB1aBC]

O teniendo en cuenta que

DeB2aBC=Transpose[B2]
DeBCaB1=Inverse[Transpose[B1]]

la matriz de la aplicación f respecto de las bases canónicas se puede expresar como

DeB2aBC.MB1B2.DeBCaB1

Ejercicio: La matriz de cierta aplicación lineal respecto de las bases canónicas es {{1, 2, -1}, {2, 1, 0}, {3, 0, 1}}. Halle la matriz de la aplicación respecto de las bases B1 y B2, donde B1 = {{1, 1, 1}, {1, -1, 0}, {0, 2, 2}} y B2 = {{2, -1, 1}, {1, -1, 0}, {0, 1, 2}}.

Ejercicio: Considere las bases B1 = {{0, 1, -1}, {1, -2, 0}, {1, 0, 0}} y B2 = {{0, 1, 1}, {1, 0, -1}, {1, -1, 0}}. Si la matriz de una aplicación lineal respecto de B1 y B2 es {{1, 0, 0}, {0, -1, 0}, {0, 0, -1}}, halle la matriz de la aplicación respecto de las bases canónicas.

Núcleo de una aplicación lineal.

Dada una aplicación f: V ⟶ W, su núcleo ker(f) está formado por todos aquellos vectores de V a los que al aplicarles f, dan como resultado el vector 0 de W.

Si fijamos una base en V y una base en W, podemos hallar la matriz de la aplicación respecto de las bases fijadas. Aplicar f a un vector es equivalente a multiplicar la matriz de la aplicacion por las coordenadas del vector en la base V. Así, los vectores del núcleo son aquellos a los que al multiplicar sus coordenadas por la matriz de la aplicación da como resultado el vector 0.

Veamos cómo hallar el núcleo de una aplicación en los siguientes ejemplos.

En  primer lugar, supongamos que al fijar ciertas bases en V y W, la aplicación f1 viene representada por la siguiente matriz

M1={{1,2,0},{0,1,0},{1,0,1},{2,3,1}}

Un vector cualquiera v del espacio V vendrá representado por sus coordenadas en la base fijada en V.

v={a1,a2,a3};

Las coordenadas de su imagen al aplicar f son

M1.v

Para determinar qué valores de v = {a1, a2, a3} hacen que M1.v valga cero, resolvemos el sistema M1.v = 0 con la siguiente instrucción.

Solve[M1.v=={0,0,0,0},{a1,a2,a3}]

Vemos que la única solución del sistema es v = {a1, a2, a3} = {0, 0, 0}. Por tanto el único vector que pertenece al núcleo es el vector cero, como consecuencia la aplicación lineal f1 es inyectiva, es decir, f1 es un monomorfismo.

En segundo lugar supongamos una aplicación f2 : V ⟶ W que tiene por matriz

M2={{1,2,0},{0,1,0},{1,3,0},{1,1,0}}

respecto de bases fijadas en V y W.

La imagen del vector de coordenas v = {a1, a2, a3} se calcula multiplicando M2.v

v={a1,a2,a3};
M2.v

Para determinar qué valores de v hacen que M2.v valga cero, resolvemos el sistema M2.v = 0 con la siguiente instrucción.

Solve[M2.v=={0,0,0,0},{a1,a2,a3}]

Vemos que el sistema es compatible indeterminado, ya que la solución debe verificar que a1 = 0 y a2 = 0, pero no hay restricción para a3, con lo que cualquier valor de a3 verificará la ecuación. Es decir el núcleo está formado por vectores de la forma {0, 0, a3} = a3.{0, 0, 1}. El vector {0, 0, 1} (dado en las coordenadas de la base fijada en V) es una base de ker(f).

En tercer lugar, suponemos que la matriz de la aplicación f3 en ciertas bases es

M3={{1,0,-1},{0,1,0},{2,0,-2},{1,2,-1}}

Para hallar el núcleo resolvemos el sistema M3.v = 0 con la siguiente instrucción

Solve[M3.v=={0,0,0,0},{a1,a2,a3}]

En este caso la solución viene dada por todos los vectores cuya primera y tercera coordenadas son iguales, y la segunda coordenada vale cero. Los vectores del núcleo son de la forma {a1, 0, a1} = a1.{1, 0, 1}. El vector {1, 0, 1} (dado en las coordenadas de la base fijada en V) es una base de ker(f).

Ejercicio: Halle el núcleo de la aplicación g : (ℝ^4) ⟶ (ℝ^2) cuya matriz respecto a las bases canónicas es {{1, 0, -1, 0}, {-1, 0, 1, 0}, {1, 1, -1, 0}, {0, 1, 0, 0}} .

Una forma más directa de hallar una base de los vectores del núcleo de una aplicación es la que emplea la orden NullSpace. Si M es la matriz de la aplicación, respecto de ciertas bases, la orden NullSpace[M] nos da una base del núcleo, expresada en la base del espacio de partida.

Hallamos de nuevo los núcleos de las aplicaciones f1, f2 y f3, ésta vez empleando la orden NullSpace.

NullSpace[M1]

NullSpace[M2]

NullSpace[M3]

Ejercicio: Mediante la instrucción NullSpace, halle el núcleo de la aplicación g : (ℝ^4) ⟶ (ℝ^2) cuya matriz respecto a las bases canónicas es {{1, 0, -1, 0}, {-1, 0, 1, 0}, {1, 1, -1, 0}, {0, 1, 0, 0}} .

Imagen de una aplicación lineal.

Dada una aplicación lineal f : V ⟶ W, la imagen de f, Im(f) , es el subespacio vectorial formado por la imagen de todos los vectores de V. Para tener un conjunto de generadores de Im(f) basta aplicar f a un conjunto de generadores de V. En particular si aplicamos f a una base de V tendremos un conjunto de generadores de Im(f).

Supongamos que la matriz de una aplicación f, respecto de ciertas bases B1 = {v1, v2, v3} y B2 = {w1, w2 w3}, es la siguiente

Mf={{1,0,1},{2,1,0},{1,2,-3}}

Como sabemos, la matriz Mf contiene por columnas las coordenadas de los vectores f(v1), f(v2) y f(v3) que acabamos de ver que son unos generadores de Im(f), así que si trasponemos la matriz Mf, obtendremos una lista con f(v1), f(v2) y f(v3) dados por sus coordenadas en B2.

Transpose[Mf]

Según hemos visto, los vectores {1, 2, 1}, {0, 1, 2} y {1, 0, -3} son unos generadores de Im(f), pero no necesariamente son una base de Im(f). Para obtener un conjunto de generadores de Im(f) que además sean linealmente independiente, aplicamos la orden RowReduce a los generadores de Im(f).

generadoresR=RowReduce[Transpose[Mf]]

De este resultado deducimos que bastan dos vectores para tener una base de Im(f), y como W tiene una base de formada por tres vectores, podemos decir que el subespacio vectorial Im(f) no es todo W, y que la aplicación f no es sobreyectiva.

Si quisiéramos hallar unas ecuaciones paramétricas o implícitas de Im(f), podríamos obtenerlas de la misma manera que vimos en la práctica 5, a partir de una base de Im(f).

base={generadoresR[[1]],generadoresR[[2]]}
parametros={a,b};
{x,y,z}==Transpose[base].{a,b}
EcParametricas=LogicalExpand[%]
EcImplicitas=Eliminate[EcParametricas,parametros]

Ejercicio: Sea f la aplicación cuya matriz respecto de las bases canónicas es {{1, 0, 1}, {1, 2, 0},{0, -2, 1}} . Halle un sistema de generadores de Im(f). Halle una base de Im(f).

Ejercicio: Sea f la aplicación dada por f(x,y,z) = (x+z, x-y, x+z). Halle unas ecuaciones implícitas de Im(f).

Veamos ahora la manera de hallar la imagen por una aplicación de un subespacio vectorial.

Consideramos de nuevo una aplicación lineal f : V ⟶ W. Si U es un subespacio de V, y tenemos que {u1, u2, ..., un} es un conjunto de generadores de U, la imagen de U (que es el subespacio vectorial que contiene todas las imágenes de los vectores de U) está generado por los vectores {f(u1), f(u2), ..., f(un)}.

Por ejemplo si U es el subespacio de (ℝ^3) generado por los vectores {1, 2, -1} y {2, 1, 0}, y f :  (ℝ^3) ⟶ (ℝ^4), dada por f(x, y, z) = (y+z, y-z, 2y, x+2y+z), para hallar un sistema de generadores de f(U), la imagen de U, basta considerar f(1, 2, -1) y f(2, 1, 0).

genU={{1,2,-1},{2,1,0}}
f[{x_,y_,z_}]={y+z,y-z,2y,x+2y+z}
genfU={f[ genU[[1]] ],f[ genU[[2]] ]}

Estos dos vectores son unos generadores de f(U), pero no necesariamente son base. Para obtener una base de f(U), empleamos la orden RowReduce.

RowReduce[genfU]

Con esto tenemos una base de f(U), y como esta base tiene dos vectores, sabemos además que los dos vectores de genfU son linealmente independientes y son una base de f(U).

Ejercicio: Sea g : (ℝ^4) ⟶ (ℝ^2)  la aplicación dada por g(x, y, z, t) = (x+z, y, t+x) , sea U el subespacio de (ℝ^4) generado por los vectores {1, 0, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}, hallar un sistema de generadores de g(U). ¿Forman una base los generadores de g(U) que ha hallado?

Otro problema que se nos puede plantear es el de hallar unas ecuaciones implícitas de un subespacio f(U) dadas unas ecuaciones implícitas de un subespacio U.

Si tenemos el subespacio U dado por sus ecuaciones implícitas, podemos hallar un sistema de generadores de U como se estudió en la práctica 5, y aplicar el procedimiento que hemos visto para obtener un sistema de generadores de f(U). Para obtener unas ecuaciones implícitas de f(U) podemos usar las ordenes LogicalExpand y Eliminate.

Vemos a continuación cómo partiendo de los vectores genfU obtenemos unas ecuaciones implícitas del subespacio vectorial f(U).

parametros={a,b};
{x,y,z,t}==Transpose[genfU].{a,b}
EcParametricas=LogicalExpand[%]
EcImplicitas=Eliminate[EcParametricas,parametros]

Ejercicios.

Para hacer los ejercicios, defina d1 con el valor de la primera cifra de su D.N.I. o pasaporte.

1- Defina la aplicación lineal g1 de forma que g1(x, y, z, t) = (d1 x+3y+z, x+t-y). Compruebe que el vector {0, 1, 0, 3} pertenece al núcleo de g1.

2- Halle la matriz, respecto de las bases canónicas, de la aplicación lineal g2 dada por g2(x, y, z) = (x+y, x+z, -y-z).

3- Considere la base BD = {{1, 6, 2}, {0, -1, -1}, {-1, 1, 6}} y la aplicación que tiene por matriz M2 = {{1, 0, -1}, {6, -1, 1},{2, -1, 6}} al considerar la base BD en el espacio de partida y en el de llegada. Compruebe que, para esta aplicación en particular, su matriz respecto de las bases canónicas es también M2.

4- La matriz de cierta aplicación respecto de las bases canónicas es M = {{5, 8, -13}, {6, 13, -16}, {6, 12, -16}}. Compruebe que respecto de la base Bd = {{-1, 2, 1}, {2, -1, 0}, {3, 1, 2}}, la matriz de dicha aplicación es una matriz diagonal.

5- Considere la aplicación f: (ℝ^3) ⟶ (ℝ^3) que tiene por matriz MB1BC = {{-1, 4, 0}, {-1, 2, 0}, {2, 2, 1}} respecto de la cierta base B1 en el espacio de partida y de la base canónica en el espacio de llegada. Sabiendo que la matriz de la aplicación respecto de las bases canónicas es MBCBC = {{5, -5, 4}, {3, -3, 2}, {0, 1, 0}}, hállese la base B1. (Sol: B1={{1, 2, 1}, {2, 2, 1}, {1, 1, 0}} ).

6- Considere la aplicación g3: (ℝ^3) ⟶ (ℝ^2) dada por g3(x, y, z) = (x+y+z, 2y-z). Resuelva el sistema lineal que verifican las coordenadas de los vectores del núcleo de g3. Compruebe el resultado usando la orden NullSpace.

7- Sea g4 : (ℝ^4) ⟶ (ℝ^3) la aplicación lineal cuya matriz respecto de las bases canónicas es (({{1, 0, 1, 0}, {-1, 7, 1, 2}, {0, 1, 0, 1}})). ¿Pueden darse unas ecuaciones implícitas de Im(g4)?

8- Estudie tanto si son inyectivas como si son sobreyectivas las aplicaciones g5: (ℝ^2) ⟶ (ℝ^4), g6: (ℝ^4) ⟶ (ℝ^2) y g7: (ℝ^3) ⟶ (ℝ^3) cuyas matrices respecto de las bases canónicas se indican a continuación.

Mg5={{1,-1},{2,0},{-1,3},{0,-2}};
Mg6={{1,2,0,-1},{0,1,3,1}};
Mg7={{1,2,-1},{2,0,1},{-3,-2,0}}

9- Compruebe que para la función g8:  (ℝ^4) ⟶ (ℝ^3) dada por g8(x, y, z, t) = (2x-z, y+t, 2z+t) se cumple la ecuación que relaciona la dimensión del núcleo y de la imagen.